#!/bin/csh -f
# +-======-+ 
#  Copyright (c) 2003-2007 United States Government as represented by 
#  the Admistrator of the National Aeronautics and Space Administration.  
#  All Rights Reserved.
#  
#  THIS OPEN  SOURCE  AGREEMENT  ("AGREEMENT") DEFINES  THE  RIGHTS  OF USE,
#  REPRODUCTION,  DISTRIBUTION,  MODIFICATION AND REDISTRIBUTION OF CERTAIN 
#  COMPUTER SOFTWARE ORIGINALLY RELEASED BY THE UNITED STATES GOVERNMENT AS 
#  REPRESENTED BY THE GOVERNMENT AGENCY LISTED BELOW ("GOVERNMENT AGENCY").  
#  THE UNITED STATES GOVERNMENT, AS REPRESENTED BY GOVERNMENT AGENCY, IS AN 
#  INTENDED  THIRD-PARTY  BENEFICIARY  OF  ALL  SUBSEQUENT DISTRIBUTIONS OR 
#  REDISTRIBUTIONS  OF THE  SUBJECT  SOFTWARE.  ANYONE WHO USES, REPRODUCES, 
#  DISTRIBUTES, MODIFIES  OR REDISTRIBUTES THE SUBJECT SOFTWARE, AS DEFINED 
#  HEREIN, OR ANY PART THEREOF,  IS,  BY THAT ACTION, ACCEPTING IN FULL THE 
#  RESPONSIBILITIES AND OBLIGATIONS CONTAINED IN THIS AGREEMENT.
#  
#  Government Agency: National Aeronautics and Space Administration
#  Government Agency Original Software Designation: GSC-15354-1
#  Government Agency Original Software Title:  GEOS-5 GCM Modeling Software
#  User Registration Requested.  Please Visit http://opensource.gsfc.nasa.gov
#  Government Agency Point of Contact for Original Software:  
#  			Dale Hithon, SRA Assistant, (301) 286-2691
#  
# +-======-+ 

#######################################################################
#                     Batch Parameters for Run Job
#######################################################################

#PBS -l walltime=@RUN_T
#PBS -l @CONVERT_P
#PBS -N @CONVERT_N
#PBS -q @RUN_Q
#PBS -W group_list=@GROUP
#PBS -j oe

#######################################################################
#                  System Environment Variables
#######################################################################

umask 022

limit stacksize unlimited

@SETENVS

#######################################################################
#           Architecture Specific Environment Variables
#######################################################################

setenv ARCH `uname`

setenv SITE             @SITE
setenv GEOSBIN          @GEOSBIN 
setenv RUN_CMD         "@RUN_CMD"
setenv GCMVER           @GCMVER

source $GEOSBIN/g5_modules
setenv LD_LIBRARY_PATH ${LD_LIBRARY_PATH}:${BASEDIR}/${ARCH}/lib

#######################################################################
#             Experiment Specific Environment Variables
#######################################################################

setenv    EXPID   @EXPID
setenv    EXPDIR  @EXPDIR
setenv    CNVDIR  @CNVDIR
setenv    HOMDIR  @HOMDIR
setenv    SCRDIR  $CNVDIR/scratch
setenv    ORGDIR  $CNVDIR/original_restarts
setenv    RSTDIR  $CNVDIR/converted_restarts

#######################################################################
#                 Create Experiment Sub-Directories
#######################################################################

if (! -e $SCRDIR) mkdir -p $SCRDIR
if (! -e $RSTDIR) mkdir -p $RSTDIR
if (! -e $ORGDIR) mkdir -p $ORGDIR

#######################################################################
#                   Clear Restarts Sub-Directories
#######################################################################

/bin/rm -f $RSTDIR/* >& /dev/null
/bin/rm -f $ORGDIR/* >& /dev/null

#######################################################################
#                   Set Experiment Run Parameters
#######################################################################

set       NX = `grep       NX: $HOMDIR/AGCM.rc | cut -d':' -f2`
set       NY = `grep       NY: $HOMDIR/AGCM.rc | cut -d':' -f2`
set  AGCM_IM = `grep  AGCM_IM: $HOMDIR/AGCM.rc | cut -d':' -f2`
set  AGCM_JM = `grep  AGCM_JM: $HOMDIR/AGCM.rc | cut -d':' -f2`
set  AGCM_LM = `grep  AGCM_LM: $HOMDIR/AGCM.rc | cut -d':' -f2`
set  OGCM_IM = `grep  OGCM_IM: $HOMDIR/AGCM.rc | cut -d':' -f2`
set  OGCM_JM = `grep  OGCM_JM: $HOMDIR/AGCM.rc | cut -d':' -f2`
>>>COUPLED<<<set       NX = `grep  OGCM_NX: $HOMDIR/AGCM.rc | cut -d':' -f2`
>>>COUPLED<<<set       NY = `grep  OGCM_NY: $HOMDIR/AGCM.rc | cut -d':' -f2`

# Set ATMOS and OCEAN Horizontal Resolution Tags
# ----------------------------------------------
set AGCM_IM_Tag = `echo $AGCM_IM | awk '{printf "%4.4i", $1}'`
set AGCM_JM_Tag = `echo $AGCM_JM | awk '{printf "%4.4i", $1}'`
set OGCM_IM_Tag = `echo $OGCM_IM | awk '{printf "%4.4i", $1}'`
set OGCM_JM_Tag = `echo $OGCM_JM | awk '{printf "%4.4i", $1}'`

>>>FVLATLON<<<set ATMOStag = DC${AGCM_IM_Tag}xPC${AGCM_JM_Tag}
>>>FVCUBED<<<set ATMOStag = CF${AGCM_IM_Tag}x6C
>>>DATAOCEAN<<<set OCEANtag = DE${OGCM_IM_Tag}xPE${OGCM_JM_Tag}
>>>COUPLED<<<set OCEANtag = TM${OGCM_IM_Tag}xTM${OGCM_JM_Tag}

#######################################################################
#   Move to Scratch Directory and Copy RC Files from Home Directory
#######################################################################

cd $SCRDIR
/bin/rm -rf * >& /dev/null
                             /bin/ln -sf $EXPDIR/RC/* .
                             /bin/cp -f  $HOMDIR/*.rc .

#######################################################################
#                        Link Boundary Datasets
#######################################################################

setenv BCSDIR   @BCSDIR
setenv SSTDIR   @SSTDIR
setenv CHMDIR   @CHMDIR
setenv BCRSLV   ${ATMOStag}_${OCEANtag}
setenv DATELINE DC

>>>COUPLED<<<setenv GRIDDIR  @COUPLEDIR/a${AGCM_IM}x${AGCM_JM}_o${OGCM_IM}x${OGCM_JM}
>>>COUPLED<<<setenv BCTAG `basename $GRIDDIR`
>>>DATAOCEAN<<<setenv BCTAG `basename $BCSDIR`

>>>OSTIA<<<set YEAR = `cat cap_restart | cut -c1-4`

set             FILE = linkbcs
/bin/rm -f     $FILE
cat << _EOF_ > $FILE
#!/bin/csh -f

>>>COUPLED<<</bin/mkdir -p RESTART
/bin/mkdir -p            ExtData
/bin/ln    -sf $CHMDIR/* ExtData

>>>COUPLED<<</bin/ln -s $GRIDDIR/SEAWIFS_KPAR_mon_clim.${OGCM_IM}x${OGCM_JM}               SEAWIFS_KPAR_mon_clim.data
>>>COUPLED<<</bin/ln -s $GRIDDIR/${BCRSLV}-Pfafstetter.til   tile.data
>>>COUPLED<<</bin/ln -s $GRIDDIR/${BCRSLV}-Pfafstetter.TRN   runoff.bin
>>>COUPLED<<</bin/ln -s $GRIDDIR/tripolar_${OGCM_IM}x${OGCM_JM}.ascii .
>>>COUPLED<<</bin/ln -s $GRIDDIR/vgrid50.ascii ./vgrid.ascii

>>>DATAOCEAN<<</bin/ln -sf $SSTDIR/@SSTFILE   sst.data
>>>DATAOCEAN<<</bin/ln -sf $SSTDIR/@ICEFILE fraci.data
>>>DATAOCEAN<<</bin/ln -sf $SSTDIR/@KPARFILE SEAWIFS_KPAR_mon_clim.data

>>>DATAOCEAN<<</bin/ln -sf $BCSDIR/$BCRSLV/${BCRSLV}-Pfafstetter.til  tile.data
>>>DATAOCEAN<<<if(     -e  $BCSDIR/$BCRSLV/${BCRSLV}-Pfafstetter.TIL) then
>>>DATAOCEAN<<</bin/ln -sf $BCSDIR/$BCRSLV/${BCRSLV}-Pfafstetter.TIL  tile.bin
>>>DATAOCEAN<<<endif

/bin/ln -sf $BCSDIR/Shared/pchem.species.CMIP-5.1870-2097.z_91x72.nc4 species.data
>>>FVCUBED<<</bin/ln -sf $BCSDIR/Shared/*bin .

/bin/ln -sf $BCSDIR/$BCRSLV/visdf_@RES_DATELINE.dat visdf.dat
/bin/ln -sf $BCSDIR/$BCRSLV/nirdf_@RES_DATELINE.dat nirdf.dat
/bin/ln -sf $BCSDIR/$BCRSLV/vegdyn_@RES_DATELINE.dat vegdyn.data
/bin/ln -sf $BCSDIR/$BCRSLV/lai_clim_@RES_DATELINE.data lai.data
/bin/ln -sf $BCSDIR/$BCRSLV/green_clim_@RES_DATELINE.data green.data
/bin/ln -sf $BCSDIR/$BCRSLV/topo_DYN_ave_@RES_DATELINE.data topo_dynave.data
/bin/ln -sf $BCSDIR/$BCRSLV/topo_GWD_var_@RES_DATELINE.data topo_gwdvar.data
/bin/ln -sf $BCSDIR/$BCRSLV/topo_TRB_var_@RES_DATELINE.data topo_trbvar.data

>>>FVCUBED<<<if(     -e  $BCSDIR/$BCRSLV/Gnomonic_$BCRSLV.dat ) then
>>>FVCUBED<<</bin/ln -sf $BCSDIR/$BCRSLV/Gnomonic_$BCRSLV.dat .
>>>FVCUBED<<<endif

>>>COUPLED<<</bin/cp -R $GRIDDIR/INPUT .
>>>COUPLED<<</bin/cp $HOMDIR/input.nml .
>>>COUPLED<<</bin/cp $HOMDIR/*_table .
>>>COUPLED<<</bin/ln -sf $GRIDDIR/cice/kmt_cice.bin .
>>>COUPLED<<</bin/ln -sf $GRIDDIR/cice/grid_cice.bin .

>>>FVCUBED<<<if(! -e input.nml ) then
>>>FVCUBED<<</bin/touch input.nml
>>>FVCUBED<<<endif

_EOF_

chmod +x linkbcs
/bin/cp  linkbcs $CNVDIR
       ./linkbcs

#######################################################################
#                 Create Binary Tile File from ASCII
#######################################################################

if (! -e tile.bin) then
$GEOSBIN/binarytile.x tile.data tile.bin
endif

#######################################################################
#          Get C2L History weights/index file for Cubed-Sphere
#######################################################################

set C_NPX = `echo $AGCM_IM | awk '{printf "%5.5i", $1}'`
set C_NPY = `echo $AGCM_JM | awk '{printf "%5.5i", $1}'`
set H_NPX = `echo @HIST_IM | awk '{printf "%5.5i", $1}'`
set H_NPY = `echo @HIST_JM | awk '{printf "%5.5i", $1}'`

set c2l_file = "${C_NPX}x${C_NPY}_c2l_${H_NPX}x${H_NPY}.bin"

if (-e $BCSDIR/$BCRSLV/${c2l_file}) /bin/ln -s $BCSDIR/$BCRSLV/${c2l_file} .

#######################################################################
#                    Get Executable and RESTARTS 
#######################################################################

/bin/cp $EXPDIR/GEOSgcm.x .

set rst_types = `cat AGCM.rc | grep "RESTART_FILE"    | cut -d ":" -f1 | cut -d "_" -f1-2`
set chk_types = `cat AGCM.rc | grep "CHECKPOINT_FILE" | cut -d ":" -f1 | cut -d "_" -f1-2`
set rst_files = `cat AGCM.rc | grep "RESTART_FILE"    | cut -d ":" -f2`
set chk_files = `cat AGCM.rc | grep "CHECKPOINT_FILE" | cut -d ":" -f2`

# Remove possible bootstrap parameter (-)
# ---------------------------------------
set dummy = `echo $rst_files`
set rst_files = ''
foreach rst ( $dummy )
  set length  = `echo $rst | awk '{print length($0)}'`
  set    bit  = `echo $rst | cut -c1`
  if(  "$bit" == "-" ) set rst = `echo $rst | cut -c2-$length`
  set rst_files = `echo $rst_files $rst`
  if(  "$rst" =~ "*fvcore_internal_rst*" ) set fv_rst = $rst
end

#######################################################################
#           Determine where and what type our restarts are
#######################################################################

if (-e $CNVDIR/$fv_rst ) then
  setenv FNDDIR $CNVDIR
else if (-e $HOMDIR/$fv_rst ) then
  setenv FNDDIR $HOMDIR
else if (-e $EXPDIR/$fv_rst ) then
  setenv FNDDIR $EXPDIR
else
  echo "Couldn't find $fv_rst. Exiting"
  exit 4
endif

echo "Using restarts from $FNDDIR"

set filetype = `/usr/bin/file -ib $FNDDIR/$fv_rst`

set fileext = `echo $fv_rst | tail - -c 5`

if ( $filetype =~ "application/x-hdf*" ) then
   set fromformat = "NetCDF4"
   set fromtype   = "pnc4"
   set fromext    = ".nc4"

   set toformat   = "binary"
   set totype     = "binary"
   set toext      = ".bin"
else
   set fromformat = "binary"
   set fromtype   = "binary"
   set fromext    = ".bin"

   set toformat   = "NetCDF4"
   set totype     = "pnc4"
   set toext      = ".nc4"
endif

if ( $fileext == "_rst" ) then
   set fromext = ""
   set toext   = ""
endif

echo "Converting from $fromformat restarts to $toformat restarts"

#######################################################################
#            Copy and Link Restarts for Conversion Run
#######################################################################

foreach rst ( $rst_files )
  if(-e $FNDDIR/$rst ) then
    /bin/cp $FNDDIR/$rst $ORGDIR
    /bin/ln -s $ORGDIR/$rst .
  endif
end

if (-e $FNDDIR/cap_restart) then
  /bin/cp $FNDDIR/cap_restart $ORGDIR
  /bin/cp $FNDDIR/cap_restart .
else
  echo "Couldn't find cap_restart in $FNDDIR. Exiting"
  exit 5
endif

>>>COUPLED<<</bin/cp $CNVDIR/RESTART/* INPUT

#######################################################################
#                 Alter CAP.rc to do a zero-length run
#######################################################################

/usr/bin/sed -i -e '/JOB_SGMT:/ s/000000[0-9][0-9]/00000000/' \
                -e '/NUM_SGMT:/ s/[0-9][0-9]*/1/' CAP.rc

#######################################################################
#                        Use a blank HISTORY.rc
#######################################################################

set FILE = HISTORY.rc
/bin/rm -f $FILE
cat << _EOF_ > $FILE

EXPID:  Convert
EXPDSC: Convert restarts

COLLECTIONS:
           ::
_EOF_

#######################################################################
#           Use sed to alter AGCM.rc to do the conversion
#######################################################################

/usr/bin/sed -r -i -e "/RESTART_TYPE:/ s/binary|pbinary|pnc4/$fromtype/" \
                   -e "/CHECKPOINT_TYPE:/ s/binary|pbinary|pnc4/$totype/" \
                   -e "/NX:/ s/[0-9][0-9]*/@CNV_NODE/" \
                   -e "/NY:/ s/[0-9][0-9]*/12/" \
                   -e "/AEROCLIM/ d" AGCM.rc

if ( $fromext != "" ) then
  /usr/bin/sed -r -i -e "/RESTART_FILE:/ s/.nc4|.bin/$fromext/" \
                     -e "/CHECKPOINT_FILE:/ s/.nc4|.bin/$toext/" AGCM.rc
endif

#######################################################################
#           Use sed to restore VEGDYN_INTERNAL_RESTART_TYPE
#######################################################################

/usr/bin/sed -r -i -e "/VEGDYN_INTERNAL_RESTART_TYPE:/ s/$fromtype/binary/" AGCM.rc

#######################################################################
#             Set Experiment Run Parameters that were altered
#######################################################################

set       NX = `grep       NX: AGCM.rc | cut -d':' -f2`
set       NY = `grep       NY: AGCM.rc | cut -d':' -f2`

# Check for Over-Specification of CPU Resources
# ---------------------------------------------
  if ($?PBS_NODEFILE) then
     set  NCPUS = `qstat -f $PBS_JOBID | grep -i Resource_List.ncpus | cut -d'=' -f2`
     @    NPES  = $NX * $NY
        if( $NPES > $NCPUS ) then
             echo "CPU Resources are Over-Specified"
             echo "--------------------------------"
             echo "Allotted NCPUs: $NCPUS"
             echo "Specified  NX : $NX"
             echo "Specified  NY : $NY"
             exit 6
        endif
     endif
  endif

##################################################################
#                Do the conversion with GEOSgcm.x
##################################################################

       @  NPES = $NX * $NY

echo "Running GEOSgcm.x to do the conversion"

set LOGFILE = "$CNVDIR/GEOSgcm.log"
/bin/rm $LOGFILE >& /dev/null

# Assume gcm_setup set these properly for the local platform
@SETENVS
$RUN_CMD $NPES ./GEOSgcm.x >& $LOGFILE

set rc =  $status

if ( $rc != 0 ) then
   echo "GEOSgcm.x failed and returned with exit code $rc"
   /bin/cat $LOGFILE
   exit $rc
else
   echo "Conversion successful!"
endif
 
#######################################################################
#             Now copy the checkpoints into $RSTDIR
#######################################################################

set rst_type_provided = ''

foreach rst (*_rst$fromext)
  # What are their prefixes?
  # ------------------------
  set rst_type_found = `echo $rst | sed -e 's/_rst.*$//'`
  set rst_type_provided = `echo $rst_type_provided $rst_type_found`
end


# Now copy the _rst to the RSTDIR
# -------------------------------
foreach rst ( $rst_type_provided )
  set chk_file = "${rst}_checkpoint${toext}"
  set rst_file = "${rst}_rst${toext}"
  echo "Copying $chk_file into $RSTDIR as $rst_file..."
  cp $chk_file $RSTDIR/$rst_file
end

# Copy over cap_restart as well
# -----------------------------
cp cap_restart $RSTDIR/