#!/bin/csh -f
# +-======-+ 
#  Copyright (c) 2003-2007 United States Government as represented by 
#  the Admistrator of the National Aeronautics and Space Administration.  
#  All Rights Reserved.
#  
#  THIS OPEN  SOURCE  AGREEMENT  ("AGREEMENT") DEFINES  THE  RIGHTS  OF USE,
#  REPRODUCTION,  DISTRIBUTION,  MODIFICATION AND REDISTRIBUTION OF CERTAIN 
#  COMPUTER SOFTWARE ORIGINALLY RELEASED BY THE UNITED STATES GOVERNMENT AS 
#  REPRESENTED BY THE GOVERNMENT AGENCY LISTED BELOW ("GOVERNMENT AGENCY").  
#  THE UNITED STATES GOVERNMENT, AS REPRESENTED BY GOVERNMENT AGENCY, IS AN 
#  INTENDED  THIRD-PARTY  BENEFICIARY  OF  ALL  SUBSEQUENT DISTRIBUTIONS OR 
#  REDISTRIBUTIONS  OF THE  SUBJECT  SOFTWARE.  ANYONE WHO USES, REPRODUCES, 
#  DISTRIBUTES, MODIFIES  OR REDISTRIBUTES THE SUBJECT SOFTWARE, AS DEFINED 
#  HEREIN, OR ANY PART THEREOF,  IS,  BY THAT ACTION, ACCEPTING IN FULL THE 
#  RESPONSIBILITIES AND OBLIGATIONS CONTAINED IN THIS AGREEMENT.
#  
#  Government Agency: National Aeronautics and Space Administration
#  Government Agency Original Software Designation: GSC-15354-1
#  Government Agency Original Software Title:  GEOS-5 GCM Modeling Software
#  User Registration Requested.  Please Visit http://opensource.gsfc.nasa.gov
#  Government Agency Point of Contact for Original Software:  
#  			Dale Hithon, SRA Assistant, (301) 286-2691
#  
# +-======-+ 


# Set and Echo Variables
# ----------------------
set arch  = `uname`
set host  = `hostname`

set name  = `echo $host`; if ( ($name =~ pfe*) || ($name =~ p4fe*) || ($name =~ r[0-9]*i[0-9]*n[0-9]*) ) set host = pleiades

set name  = `echo $host | cut -b 1-8` ; if( $name == 'columbia' ) set host = $name
set name  = `echo $host | cut -b 1-8` ; if( $name == 'discover' ) set host = $name
set name  = `echo $host | cut -b 1-3` ; if( $name == 'vis'      ) set host = discover
set name  = `echo $host | cut -b 1-4` ; if( $name == 'borg'     ) set host = discover
set name  = `echo $host | cut -b 1-4` ; if( $name == 'warp'     ) set host = discover
set name  = `echo $host | cut -b 1-4` ; if( $name == 'dali'     ) set host = discover
                                        if( $name == 'cfe1'     ) set host = columbia
                                        if( $name == 'cfe2'     ) set host = columbia
                                        if( $name == 'e1'       ) set host = palm
                                        if( $name == 'e2'       ) set host = palm
                                        if( $name == 'e3'       ) set host = palm

# Set Environment Variables
# -------------------------
if ($?GRADSX) then 
     set gradsx = $GRADSX
else
     set gradsx = gradsnc4
endif

if( $arch == 'OSF1'     )     setenv VERIFICATION /share/ltakacs/verification

if( $arch == 'IRIX64'   ) then
    if( $host == 'dirac'    ) then
                              setenv VERIFICATION /share/ltakacs/verification
                              setenv OPENGADIR    /share/dasilva/opengrads
                              setenv GAVERSION     IRIX64-1.9.8
                              setenv GRADS_LOC    ${OPENGADIR}/${GAVERSION}
                              setenv GADDIR       ${OPENGADIR}/dat
                              setenv GRADS        ${GRADS_LOC}/gradshdf
                              setenv ImagMag_lib  /ford1/local/irix6.2/lib
                              setenv ImagMag_bin  /ford1/local/irix6.2/bin
                              setenv PATH         "${GRADS_LOC}/bin":${ImagMag_bin}:$PATH
                              set    path =     ( "${GRADS_LOC}/bin" ${ImagMag_bin} $path )
    endif
endif

if( $arch == 'Linux'    ) then
    if( $host == 'pleiades' ) then
                              setenv VERIFICATION /nobackup/ltakacs/verification
                              setenv OPENGADIR    /u/dkokron/play/opengrads
                              setenv GAVERSION    /Linux-1.9-rc1-gmao
                              setenv GRADS_LOC    ${OPENGADIR}/${GAVERSION}
                              setenv GRADS        ${GRADS_LOC}/$gradsx
                              setenv GRAUDX       ${GRADS_LOC}/gex/
                              setenv GADDIR       ${OPENGADIR}/dat/
                              setenv GRADSBIN     ${GRADS_LOC}
                              setenv GXYAT        ${OPENGADIR}/Linux-1.9-rc1/gxyat
                              setenv ImagMag_lib  /nasa/imagemagick/6.4.0-3/lib
                              setenv ImagMag_bin  /nasa/imagemagick/6.4.0-3/bin
                              setenv PATH         "${GRADS_LOC}":${ImagMag_bin}:$PATH
                              set    path =     ( "${GRADS_LOC}" ${ImagMag_bin} $path )
    endif
    if( $host == 'discover' ) then
                              setenv NCCS_SHARE   ${SHARE}/dao_ops/
                              setenv VERIFICATION ${NCCS_SHARE}/verification
                              setenv OPENGADIR    /home/dao_ops/operations/GrADS
                              setenv GAVERSION     "current"
                              setenv GRADS_LOC    ${OPENGADIR}/${GAVERSION}
                              setenv GRADS        ${GRADS_LOC}/$gradsx
                              setenv GRAUDX       ${GRADS_LOC}/gex/
                              setenv GADDIR       ${OPENGADIR}/dat/
                              setenv GRADSBIN     ${GRADS_LOC}
                              setenv GXYAT        ${NCCS_SHARE}/opengrads/Linux-1.9-rc1/gxyat
                              setenv ImagMag_lib  ${NCCS_SHARE}/lib
                              setenv ImagMag_bin  ${NCCS_SHARE}/bin
                              setenv PATH         ${PATH}:"${GRADS_LOC}/bin":${ImagMag_bin}
                              set    path =     ( ${path} "${GRADS_LOC}/bin" ${ImagMag_bin} )
    endif
    if( $host == 'columbia' ) then
                              setenv VERIFICATION /nobackup2b/ltakacs/verification
                              setenv OPENGADIR    /u/dkokron/play/opengrads
                              setenv GAVERSION     Linux-1.9-rc1-gmao
                              setenv GRADS_LOC    ${OPENGADIR}/${GAVERSION}
                              setenv GADDIR       ${OPENGADIR}/dat
                              setenv GRADS        ${GRADS_LOC}/$gradsx
                              setenv GRAUDX       ${GRADS_LOC}/gex/
                              setenv ImagMag_lib  /nasa/pd/imagemagick/6.3.2/lib
                              setenv ImagMag_bin  /nasa/pd/imagemagick/6.3.2/bin
                              setenv PATH         "${GRADS_LOC}/bin":${ImagMag_bin}:$PATH
                              set    path =     ( "${GRADS_LOC}/bin" ${ImagMag_bin} $path )
    endif
    if( $host == 'palm'     ) then
                              setenv VERIFICATION /share/ltakacs/verification
                              setenv OPENGADIR    /share/dasilva/opengrads
                              setenv GAVERSION     Linux-1.9.7
                              setenv GRADS_LOC    ${OPENGADIR}/${GAVERSION}
                              setenv GADDIR       ${OPENGADIR}/dat
                              setenv GRADS        ${GRADS_LOC}/gradshdf
                              setenv GRAUDX       ${GRADS_LOC}/gex/
                              setenv ImagMag_lib  /gmao_ops/dao_ops/ALTIX/lib
                              setenv ImagMag_bin  /gmao_ops/dao_ops/ALTIX/bin
                              setenv PATH         "${GRADS_LOC}/bin":${ImagMag_bin}:$PATH
                              set    path =     ( "${GRADS_LOC}/bin" ${ImagMag_bin} $path )
    endif
endif


# Set GRADS Environment Variables
# -------------------------------
setenv  GASCRP $GEOSUTIL/plots/grads_util
setenv  GAUDFT $GEOSUTIL/plots/grads_util/udft_$arch.tools
setenv  GAUDXT $GEOSUTIL/plots/grads_util/udxt

if(  -e sedfile ) /bin/rm  sedfile
cat >   sedfile << EOF
s?GEOSUTIL?$GEOSUTIL?g
s?ARCH?$arch?g
EOF
sed -f sedfile $GASCRP/udft.template > $GAUDFT


# Build Grads UDF Utilities
# -------------------------
set files = `echo regrid2`
foreach file ($files)
   if(! -e $GASCRP/${file}_$arch.x ) then
     if( $arch == 'IRIX64' ) f90   -o $GASCRP/${file}_$arch.x $GASCRP/${file}.f
     if( $arch == 'OSF1'   ) f90   -o $GASCRP/${file}_$arch.x $GASCRP/${file}.f
     if( $arch == 'Linux'  ) ifort -o $GASCRP/${file}_$arch.x $GASCRP/${file}.f
   endif
end


# Create .cshrc for QuickPlot (Note: unsetenv GAUDXT to removed Arlindo Setup Conflicts)
# --------------------------------------------------------------------------------------
if( -e .quickplotrc ) /bin/rm .quickplotrc
echo \#\!/bin/csh                                                >  .quickplotrc
echo   setenv VERIFICATION $VERIFICATION                         >> .quickplotrc
echo   setenv LOCHOST $host                                      >> .quickplotrc
echo   setenv GRADS  $GRADS                                      >> .quickplotrc
echo   setenv GXYAT  $GXYAT                                      >> .quickplotrc
echo   setenv GRAUDX $GRAUDX                                     >> .quickplotrc
echo   setenv GADDIR $GADDIR                                     >> .quickplotrc
echo   setenv GASCRP $GASCRP                                     >> .quickplotrc
echo   setenv GAUDFT $GAUDFT                                     >> .quickplotrc
echo   setenv GAUDXT $GAUDXT                                     >> .quickplotrc
echo   "  "                                                      >> .quickplotrc
echo "set path = ( $path $GRADS_LOC $GASCRP )"                   >> .quickplotrc

if ( $?LD_LIBRARY_PATH ) then
     if !( $LD_LIBRARY_PATH =~ *${GADDIR}* ) then
           echo setenv LD_LIBRARY_PATH ${GRAUDX}:${GADDIR}:${ImagMag_lib}:${LD_LIBRARY_PATH}:/opt/gnome/lib >> .quickplotrc
     endif
else
           echo setenv LD_LIBRARY_PATH ${GRAUDX}:${GADDIR}:${ImagMag_lib}:/opt/gnome/lib                    >> .quickplotrc
endif
echo   "  "                                                                                                 >> .quickplotrc

if( $host == 'pleiades' ) echo setenv LD_LIBRARY_PATH ${GRAUDX}:/u/dkokron/lib/gxyat:${LD_LIBRARY_PATH} >> .quickplotrc

chmod 755 .quickplotrc