function keg (args)

expdsc = subwrd(args,1)
output = subwrd(args,2)

'getenv "GEOSUTIL"'
         geosutil = result
'getinfo tdim'
         tdim = result

'set t 1 'tdim


* Compute Total, Dry, and Moist Instantaneous Values
* --------------------------------------------------
'define qtot = VAR1g/100'
'define qdry = VAR1g/100-(VAR2g+VAR3g+VAR4g+VAR5g)/9.8'
'define qmst =           (VAR2g+VAR3g+VAR4g+VAR5g)/9.8'


* Compute Total, Dry, and Moist Time-Averaged Values
* --------------------------------------------------
'define qtotave = ave(qtot,t=1,t='tdim')'
'define qdryave = ave(qdry,t=1,t='tdim')'
'define qmstave = ave(qmst,t=1,t='tdim')'


* Rescale Moist to have Equivalent Dry Time-Average
* -------------------------------------------------
'define qmst = qmst - qmstave + qdryave'


'run minmax qtot'
       tmax = subwrd(result,1)
       tmin = subwrd(result,2)
'run minmax qdry'
       dmax = subwrd(result,1)
       dmin = subwrd(result,2)
'run minmax qmst'
       mmax = subwrd(result,1)
       mmin = subwrd(result,2)

if( mmax > dmax ) ; dmax = mmax ; endif
if( mmin < dmin ) ; dmin = mmin ; endif

    tdif = tmax-tmin
    ddif = dmax-dmin
if( tdif > ddif ) ; ddif = tdif ; endif

* Plot Total Mass
* ---------------
'set vpage 0 11 3.9 8.4'

'set grads off'
'set ylab %.2f'

'set t 1'
'd qtotave'
pltave = subwrd(result,4)
pltmax = pltave + 0.6*ddif
pltmin = pltave - 0.6*ddif

'set t 1 'tdim
'set axlim 'pltmin' 'pltmax

'set cmark  0'
'set cstyle 1'
'set ccolor 2'
'set cthick 6'
'd qtot'
'set cmark  0'
'set cstyle 1'
'set ccolor 2'
'set cthick 1'
'd qtotave'

* Plot Time-Average Values
* ------------------------
'set t 'tdim
'getinfo date'
         date = result
'd qtotave'
   qtotave = subwrd(result,4)

'q w2xy 'date' 'qtotave
    ytot = subwrd(result,6)

'set strsiz .08'

 'set string 1 l 5'
 'draw string 10.52 'ytot ' 'qtotave


* Plot Dry Mass and QV
* --------------------
'set vpage 0 11 0 4.5'

'set grads off'
'set ylab %.2f'

'set t 1'
'd qdryave'
pltave = subwrd(result,4)
pltmax = pltave + 0.6* ddif
pltmin = pltave - 0.6* ddif

'set t 1 'tdim
'set axlim 'pltmin' 'pltmax

'set cmark  0'
'set cstyle 1'
'set ccolor 4'
'set cthick 6'
'd qdry'
'set cmark  0'
'set cstyle 1'
'set ccolor 4'
'set cthick 1'
'd qdryave'
'set cmark  0'
'set cstyle 1'
'set ccolor 2'
'set cthick 6'
'd qmst'


* Plot Time-Average Values
* ------------------------
'set t 'tdim
'getinfo date'
         date = result
'd qdryave'
   qdryave = subwrd(result,4)

'q w2xy 'date' 'qdryave
    ytot = subwrd(result,6)

'set strsiz .08'

 'set string 1 l 5'
 'draw string 10.52 'ytot ' 'qdryave

'set vpage off'
'set string 1 c 6'
'set strsiz .14'
'draw string 6.15 8.25 'expdsc
'draw string 6.15 7.95 Globally Integrated Surface Pressure (mb)'
'draw string 6.15 4.00 Dry Surface Pressure and Scale-Adjusted Vapor Pressure (mb)'

'myprint -name 'output'/PS_TIME_SERIES'
return